' Copyright 2010 ESRI
' 
' All rights reserved under the copyright laws of the United States
' and applicable international laws, treaties, and conventions.
' 
' You may freely redistribute and use this sample code, with or
' without modification, provided you include the original copyright
' notice and use restrictions.
' 
' See the use restrictions.
' 

Imports Microsoft.VisualBasic
Imports System
Public Class PolygonTool
    Implements ESRI.ArcGIS.ADF.Web.UI.WebControls.Tools.IMapServerToolAction
  #Region "IMapServerToolAction Members"

  Private Sub ServerAction(ByVal toolEventArgs As ESRI.ArcGIS.ADF.Web.UI.WebControls.ToolEventArgs) Implements ESRI.ArcGIS.ADF.Web.UI.WebControls.Tools.IMapServerToolAction.ServerAction
    ' Get a reference to the Map control on which the tool was executed
    Dim adfMap As ESRI.ArcGIS.ADF.Web.UI.WebControls.Map = CType(toolEventArgs.Control, ESRI.ArcGIS.ADF.Web.UI.WebControls.Map)

    ' Get the polygon drawn by the user
    Dim mapPolygonEventArgs As ESRI.ArcGIS.ADF.Web.UI.WebControls.MapPolygonEventArgs = CType(toolEventArgs, ESRI.ArcGIS.ADF.Web.UI.WebControls.MapPolygonEventArgs)
    Dim mapPolygon As ESRI.ArcGIS.ADF.Web.Geometry.Polygon = mapPolygonEventArgs.MapPolygon

    ' Convert the Web ADF input polygon to its ArcGIS Server data source specific equivalent
    Dim agsSoapPolygon As ESRI.ArcGIS.ADF.ArcGISServer.PolygonN = ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.Converter.FromAdfPolygon(mapPolygon)

    ' Get an ArcGIS Server specific map functionality.  Note this code assumes the existence of an ArcGIS
    ' Server resource item with the name "MapResourceItem0"
    Dim agsMapFunctionality As ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality = CType(adfMap.GetFunctionality("MapResourceItem0"), ESRI.ArcGIS.ADF.Web.DataSources.ArcGISServer.MapFunctionality)

    ' Get the ArcGIS Server MapDescription for the resource
    Dim agsSoapMapDescription As ESRI.ArcGIS.ADF.ArcGISServer.MapDescription = agsMapFunctionality.MapDescription

    ' Create a yellow ArcGIS Server data source specific color object
    Dim agsSoapRgbColor As ESRI.ArcGIS.ADF.ArcGISServer.RgbColor = New ESRI.ArcGIS.ADF.ArcGISServer.RgbColor()
    agsSoapRgbColor.Red = 255
    agsSoapRgbColor.Green = 255
    agsSoapRgbColor.Blue = 0

    ' Initialize an ArcGIS Server data source specific fill symbol with a solid fill and the color initialized above
    Dim agsSoapSimpleFillSymbol As ESRI.ArcGIS.ADF.ArcGISServer.SimpleFillSymbol = New ESRI.ArcGIS.ADF.ArcGISServer.SimpleFillSymbol()
    agsSoapSimpleFillSymbol.Style = ESRI.ArcGIS.ADF.ArcGISServer.esriSimpleFillStyle.esriSFSSolid
    agsSoapSimpleFillSymbol.Color = agsSoapRgbColor

    ' Create an ArcGIS Server data source specific polygon element with the fill symbol and input polygon
    Dim agsSoapPolygonElement As ESRI.ArcGIS.ADF.ArcGISServer.PolygonElement = New ESRI.ArcGIS.ADF.ArcGISServer.PolygonElement()
    agsSoapPolygonElement.Symbol = agsSoapSimpleFillSymbol
    agsSoapPolygonElement.Polygon = agsSoapPolygon

    ' If the current resource does not have any custom graphics specified, initialize this property with
    ' a new array with just the newly created graphic element.  Otherwise, create a new array with both
    ' the current custom graphics and teh newly created element.
    If Not agsSoapMapDescription.CustomGraphics Is Nothing Then
      ' Create a new ArcGIS Server graphic element array with a size that is one bigger than the
      ' resource's current element array
      Dim elementCount As Integer = agsSoapMapDescription.CustomGraphics.Length
      Dim agsSoapGraphicElementArray As ESRI.ArcGIS.ADF.ArcGISServer.GraphicElement() = New ESRI.ArcGIS.ADF.ArcGISServer.GraphicElement(elementCount){}

      ' Copy the resource's current element graphic array to the new array
      agsSoapMapDescription.CustomGraphics.CopyTo(agsSoapGraphicElementArray, 0)

      ' Add the newly created polygon element to the array
      agsSoapGraphicElementArray(elementCount) = agsSoapPolygonElement

      ' Update the resource's element array with the new array
      agsSoapMapDescription.CustomGraphics = agsSoapGraphicElementArray
    Else
      ' Create a new ArcGIS Server graphic element array with only the newly created polygon element
      Dim agsSoapGraphicElement As ESRI.ArcGIS.ADF.ArcGISServer.GraphicElement() = New ESRI.ArcGIS.ADF.ArcGISServer.GraphicElement(0){}
      agsSoapGraphicElement(0) = agsSoapPolygonElement

      ' Update the resource's element array with the new array
      agsSoapMapDescription.CustomGraphics = agsSoapGraphicElement
    End If

    ' Refresh the resource so the new polygon is shown
    adfMap.RefreshResource(agsMapFunctionality.Resource.Name)
  End Sub

  #End Region
End Class